ABCelectronique : portail d'information dans le domaine de l'électronique
Home » Diverses rubriques » Archive forum sujets+corp
 
     
   Transformaneur Haute Frequence de 200 volts a 3 kv  
Je suis à la recherche d’information.
Sur un transfo. A Haute fréquence de 100 kHz
de 200 volts au primaire et obtenir 300 kV a la sortie.

Si vous avez des idées.
Merci de votre intervention.


Numéro de l'article: 9401   |  De: Roger Landry   |  Date: 2002-08-25 21:05:56

   anémométre  
Bonjour,
Je voudrais fabriquer un anémometre,et je recherche des schémas ou des adresses de site,aussi des schemas pour fabriquer des fréquencemetres simple pour faire des comptours

merci

Numéro de l'article: 9402   |  De: Laurent   |  Date: 2002-08-25 22:54:26

   questions sur Eagle  
Salut,

Toutes les librairies de Eagle contiennent des pastilles avec des trous énormes alors que pour un percage correct à la main, il vaut mieux un petit evidement de 0,25 pour centrer le foret. Est-ce qu'il existe un moyen simple et rapide de modifier toutes les pastilles d'un circuit ou des librairies pour avoir un evidement de 0,25.

merci d'avance
fthierry

Numéro de l'article: 9411   |  De: fthierry   |  Date: 2002-08-26 10:27:56
   RE: questions sur Eagle
ça m'interesse aussi
en effet, les pastilles sont beaucoup trop petites et les trous trop gros!

Numéro de l'article: 9424   |  De: Petrus   |  Date: 2002-08-26 14:16:13
   projet de fin d'étude
Je viens tres respectueusement sollisite votre haut
veillance de bien vouloir m'accorde ma demande a votre organisme
je suis TS en électronique industriel et je cherche un
theme simple avac réalisation pratique dans mon demaine si vous
pouvez de me proposé un théme avec des schémas principale et
leur étude thiorique par ce que j'ai pas les moyen
Dans l'attente d'une suite favorable
veillez agréer monsieur de mon profond respect

voila mon adresse:
5Rue magarfi youcefe hamouali-tafraoui
ORAN(ALGERIE) CP:31160

Numéro de l'article: 9431   |  De: hadj dida bloufa   |  Date: 2002-08-26 17:29:39
   projet de fin d'étude
Je viens tres respectueusement sollisite votre haut
veillance de bien vouloir m'accorde ma demande a votre organisme
je suis TS en électronique industriel et je cherche un
theme simple avac réalisation pratique dans mon demaine si vous
pouvez de me proposé un théme avec des schémas principale et
leur étude thiorique par ce que j'ai pas les moyen
Dans l'attente d'une suite favorable
veillez agréer monsieur de mon profond respect

voila mon adresse:
5Rue magarfi youcefe hamouali-tafraoui
ORAN(ALGERIE) CP:31160

Numéro de l'article: 9433   |  De: hadj dida bloufa   |  Date: 2002-08-26 17:31:45

   digitaliseur image  
bonjour,
Je souhaite réaliser un système autonome permettant de capturer des images à l'aide d'une caméra vidéo et de les visualiser sur un moniteur ou un téléviseur, sans utiliser un PC.
Si vous avez des idées ( schémas, type de composants, constructeurs etc...)merci par avance.
Daniel


Numéro de l'article: 9412   |  De: daniel   |  Date: 2002-08-26 10:56:24

   Schéma cablage Nvidia TV out  
Bonjour,

J'ai une carte écran Nvidia avec sortie TV, c'est une fiche PS2 ou l'on raccorde un adaptateur qui sort en Y/C et composite (que je n'ai pas).
Si qlq connais le schéma de cablage pour pouvoir connecter ma TV avec une fiche PS2, merci de me le faire savoir.

A+
Ren

Numéro de l'article: 9413   |  De: Ren   |  Date: 2002-08-26 10:57:36
   RE: Schéma cablage Nvidia TV out
salut,
tu as fait un tour à hardwarebook pour voir !
http://www.hardwarebook.net/connector/index.html

a+

Numéro de l'article: 9416   |  De: Fabrice   |  Date: 2002-08-26 12:40:47
   RE: Schéma cablage Nvidia TV out
oui, merci
mais il n'y a pas... :-(

Numéro de l'article: 9417   |  De: Ren   |  Date: 2002-08-26 12:57:11
   RE: Schéma cablage Nvidia TV out
C'est parti............en JPEG

Numéro de l'article: 9604   |  De: Spike   |  Date: 2002-08-29 01:11:18

   Fabriquer ses self  
Salut,
je souhaiterais fabriquer mes self de puissance pour des alim a decoupage. Seulement voila je n'arrive pas a trouver du fil de cuivre emailler d'un diametre superieur a 1,2mm.
Alors si kk1 connais un site qui vent ca, merci de me le communiquer.

Sinon, est-il possible de réaliser ses self avec du fil electronqiue monobrin (ou multibrin) utiliser habituelement comme conducteur electrique. Je parle du fil normale, avec la gain en caoutchouc autour :-)

Merci poiur votre aide :-)

Numéro de l'article: 9414   |  De: RolLie_TyLer_HC11   |  Date: 2002-08-26 11:27:29
   RE: Fabriquer ses self
Salut,
As-tu pensé à demander à un atelier de bobinage, en général, il sont sympas.
Des bobines avec du fil gainé existent, ça devrait pouvoir se faire en s'assurant que le fil ne chauffera pas de trop et faire fondre l'isolant.

Fas54.

Numéro de l'article: 9425   |  De: fas54   |  Date: 2002-08-26 14:31:12

   emission satellite  
bonsoir tous !
je cherche un montage emetteur recepteur satellite neanmoins l'emetteur, SVP.
merci.

Numéro de l'article: 9415   |  De: malion   |  Date: 2002-08-26 12:38:10
   RE: emission satellite
www.tdf.fr

Je suis sur qu'ils ont des emetteurs de poche ;-)

Numéro de l'article: 9477   |  De: fthierry   |  Date: 2002-08-27 10:29:08

   24w166  
je souhaite programmer le 24w166 mais je n'arrive pas à trouver sur internet les instructions et comment les utilisées. Si quelqu'un les connait, merci de me les envoyées. Merci


Numéro de l'article: 9426   |  De: milas   |  Date: 2002-08-26 15:02:23

   Minuteur / Chronomètre  
Bonjour,

J'ai une idée de manip' et je n'arrive pas à la réaliser.

Je voudrais, après avoir appuyé sur un bouton poussoir, allumer 30 lampes ou LED, et je voudrais qu'elles s'éteignent une par une (Comme un décompte).
Si possible, le temp devrait être réglable, et un buzzer retentirai à la fin.

Si quelqu'un a une piste...

Merci d'avance
JF

Numéro de l'article: 9427   |  De: Jean-François   |  Date: 2002-08-26 15:20:12
   RE: Minuteur / Chronomètre
Je peux te réaliser ton application car elle ne demande pas beaucoups
d'effort ;

Je te propose de le faire avec un PIC16F628 et 4 PCF8574 ou 74574 m'est le PCB est plus compliquer .

Le réglage de l'intervale ce fera par un potentiomètre .

Je peut te faire la partie commande , càd schémas principe et programme pour le pic . Il ne te restera plus qua mettre des LED ou alors des triack pour 220V.

Si ca t'interesse bhen je te fait ca non problèmes ....

A+


Numéro de l'article: 9443   |  De: byte   |  Date: 2002-08-26 18:55:48
   RE: Minuteur / Chronomètre
Je te remercie pour ta réponse,

Pour te parler franchement, je n'ai pas penser au µP car je n'en ai jamais utilisé!

Si tu peux faire ce que tu m'as dit, alors c'est super génial!!!!
A+

JF

Numéro de l'article: 9483   |  De: Jean-François   |  Date: 2002-08-27 11:53:35

   cherche qqch ou un magasin pr fabriquer interface  
Bonjour,
j'aurais voulu savoir si qqch ou un magasin était capable de réaliser une interface PC (pour lire une eprom) si je lui apporte l'eeprom.

Merci d'avance de m'aider, je possède le typon et le matos.

Cordialement.

Numéro de l'article: 9428   |  De: xavier   |  Date: 2002-08-26 15:21:12
   RE: cherche qqch ou un magasin pr fabriquer interf
Salut,
Que veux-tu exactement, lire l'eprom ou fabriquer une carte spécialement pour la lire ?.
Quel genre d'eprom ?
Dans quelle région es-tu ?

Fas54.

Numéro de l'article: 9435   |  De: fas54   |  Date: 2002-08-26 17:38:44

   composant  
je cherche de la doc sur un circuit integre le SL 441 C

Numéro de l'article: 9432   |  De: didier   |  Date: 2002-08-26 17:30:40
   RE: composant
Bonjour,

Tu trouveras dans ta BàL une ancienne doc sur l'utilisation des circuits SL440 et 441.

J'espère que ça te conviendra.

@+

André01

Numéro de l'article: 9468   |  De: André01   |  Date: 2002-08-27 07:29:06

   PLATINE DVD  
Quelqu'un connait il une platine de salon pouvant lire les mp4
il parait que ca exite en rajoutant le logiciel dans la prom de
l'appareil

Numéro de l'article: 9434   |  De: didier   |  Date: 2002-08-26 17:32:35
   RE: PLATINE DVD
Chez JVC, il y en a un qui lit les DIVX, si c'est ca que tu recherches.

Numéro de l'article: 9440   |  De: Ren   |  Date: 2002-08-26 18:43:05
   RE: PLATINE DVD
OUI
as tu la référence de cette platine jvc
merci d'avance

Numéro de l'article: 9481   |  De: TUAL   |  Date: 2002-08-27 11:13:00

   chargeur solaire de baterie de camescope  
Je cherche des infos en vue de construire un chargeur solaire de baterie de camescope :
- où trouver des cellules photoVoltaique pas cher
- Quels montages ?
- Quels sont les piege à éviter ?

Est-ce que ca vous semble compliqué (je débute)
Merci pour votre réponse (par mail si possible)
opouydebat@esrifrance.fr

Numéro de l'article: 9436   |  De: pouydebat   |  Date: 2002-08-26 17:39:05
   RE: chargeur solaire de baterie de camescope
Bonjour,

Le montage en lui même, n'est pas difficile, mais par contre le cout de revient et le rendement, n'en vaut pas la chandelle, enfin c'est ce que je pense !

Il faut déjà du soleil ! hé oui, la nuit, marche pas !
C'est une charge très lente (24h min)
Le prix des plaques, (il en faudra au moins 7-9) est très cher.
Mais pourquoi veut-tu faire un montage pareil ????
Je ne vois aucun avantage à ce montage, si ce n'est recharger les batteries dans une île déserte sans électricité !

A+

Numéro de l'article: 9439   |  De: Ren   |  Date: 2002-08-26 18:42:24
   RE: chargeur solaire de baterie de camescope
salut ,

Ren a raison, cela semble pas tres raisonnable comme histoire, surtout que tu motive le mot "PAS CHER" dans ton post, C'est incompatible solair et Pas cher !!


A++

cacam

Numéro de l'article: 9475   |  De: cacam   |  Date: 2002-08-27 10:20:44

   télécommande univ TV  
je souhaite metre en service une télécommande marque D2 achetée en grande surface

où trouver le mode d'emploi ?

Numéro de l'article: 9437   |  De: phili^ppe   |  Date: 2002-08-26 18:20:41

   ATtiny22  
QQ'un sait'il où on peut encore trouver le défunt ATtiny22 (normal ou L) dans le commerce ?
Merci d'avance

Numéro de l'article: 9449   |  De: Arsach   |  Date: 2002-08-26 20:14:44

   Pas de DB9?  
Bonjiur,

je cherche le moyen le plus simple d'obtenir un port série sur un
portable qui n'en a pas. Ce dans le but de gérer des programmateurs.
USB --> DB9 ?
// --> DB9 ?
PCMCIA --> DB9 ?
Si quelqu'un a une idée?

Merci.

Numéro de l'article: 9450   |  De: nicomat62   |  Date: 2002-08-26 20:30:23
   RE: Pas de DB9?
Il existe des convertiseurs USB=> RS232 chez tous les distributeurs
informatiques .

Le construire soit même coûterais plus chers ...



Numéro de l'article: 9451   |  De: byte   |  Date: 2002-08-26 20:46:32
   RE: Pas de DB9?
Il existe des convertiseurs USB=> RS232 chez tous les distributeurs
informatiques .

Le construire soit même coûterais plus chers ...



Numéro de l'article: 9452   |  De: byte   |  Date: 2002-08-26 20:46:32
   RE: Pas de DB9?
Attention tout de meme, certains systemes ne fonctionnent pas avec ces adaptateurs.

Numéro de l'article: 9470   |  De: fthierry   |  Date: 2002-08-27 08:58:58
   RE: Pas de DB9?
C'est la qu'est le problème!!

Merci à tous.

Numéro de l'article: 9476   |  De: nicomat62   |  Date: 2002-08-27 10:29:00

   ps2  
cherche reparateur ps2

Numéro de l'article: 9454   |  De: stef   |  Date: 2002-08-26 21:22:45

   plan électronique  
Quelqu'un sait-il me dire s'il y a un site ou je pourrais trouver des plans électroniques de différentes marques de télévisions?
Merci d'avance .

Numéro de l'article: 9455   |  De: lau   |  Date: 2002-08-26 21:33:47
   RE: plan électronique
MOI AUSSI JE RECHERCHE DES SHEMA STRUCTUREL DE TELE

Numéro de l'article: 9456   |  De: GREG   |  Date: 2002-08-26 22:04:17
   RE: plan électronique
http://membres.lycos.fr/coronelle/schnewtot.htm

A+

Numéro de l'article: 9462   |  De: Ren   |  Date: 2002-08-26 22:50:45
   RE: plan électronique
Bonjour,

On peut compléter par les sites suivants :

-ftp://147.213.13.111/schemy/TV/
-http://cxema.ru/Video/
-http://monitor.ti.ru:8101/shem/tv/
-http://schematv.chez.tiscali.fr
-http://www.rlocman.com.ru/en/
-http://www.robot.hpg.com.br/esqtv.htm
-http://www.schema99.d2.cz/tv.htm
-http://www.promelec.ru/schemes_list.html?7

et il y en a sûrement bien d'autres....

pour le Webmaster : ne serait-il pas possible de constituer une liste de liens sur une page du site "abcelectronique" qui pourrait être complétée au fur et à mesure des découvertes de chacun ?

André01

Numéro de l'article: 9469   |  De: André01   |  Date: 2002-08-27 08:20:36
   RE: plan électronique
Bonsoir à tous,
excellente suggestion d'André pour cette liste de liens.
Et encore ceux-ci, pas uniquement pour les TV d'ailleurs:
A+

http://www.geocities.com/monitorss/links.html
http://monitorworld.com/monitors_home.html
http://schematv.chez.tiscali.fr/
http://bama.sbc.edu/
http://www.electronix.com/catalog/
http://www.circuitarchive.co.uk/heath.htm


Numéro de l'article: 9500   |  De: Jean-Pierre   |  Date: 2002-08-27 18:30:22
   composant
exist'il un composant qui chauffe,quand le courant le traverse dans un sens,et refroidit avec une inversion de polaritè (je croit avoir vue ça! a moins que j'ai fait un reve! ) merçi a tous!

Numéro de l'article: 9514   |  De: henry   |  Date: 2002-08-27 22:39:07
   RE: composant
Oui, ca existe.
Ca s'appelle "peletier".
C'est une plaque qui chauffe d'un cotes et refroidis de l'autre, et inversement si tu inverses la polarité.

Pour les schèmas, il y a ca aussi: http://www.microelectronic.co.yu/links/free_download.htm

A+

Numéro de l'article: 9518   |  De: Ren   |  Date: 2002-08-27 23:14:10

   caméra invisible  
j'aimerais achetez une caméra discrete pour enregistrer ma chambre,je peut la racorder a mon pc.j'aimerais une caméra qui a l'apparence d'autre chose(modem,hub....).Biensur le moin cher possible,en couleur,une portée de 3m voir 4m.
J'espère que vous pourrez m'aidez et me conseiller.
merci

Numéro de l'article: 9459   |  De: axel   |  Date: 2002-08-26 22:36:34
   RE: caméra invisible
www.conrad.fr

Numéro de l'article: 9473   |  De: cacam   |  Date: 2002-08-27 10:09:25

   Magnetoscope toshiba V863F  
Bonjour,

L'alim de mon scope toshiba V863F semble avoir rendu l'âme. Est ce que quelqu'un aurait le schema de câblage de cette alim ainsi que la nomenclature des composants?
Merci de votre aide.

Numéro de l'article: 9463   |  De: sam   |  Date: 2002-08-26 22:53:50
   RE: Magnetoscope toshiba V863F
Pas de shema mais si ton alime est en bloc separ verif transi si pas en c/c si non change les capa chimi du primaire (autour du transi)

Numéro de l'article: 9524   |  De: Spike   |  Date: 2002-08-28 01:31:33

   Luminosité moniteur Samsung SyncMaster 750s  
Bien que la luminosité et le contraste réglés à fond, l'image est encore sombre.

J'ai lu qu'en jouant sur le réglage Screen sur le THT pourrait améliorer les choses, mais ce réglage n'existe pas !

Voici les 2 réglages dispo sur le THT : focus H et focus V



Quelqu'un aurait-il une idée ?



D'avance merci.

Numéro de l'article: 9465   |  De: Christian   |  Date: 2002-08-26 23:48:28
   RE: Luminosité moniteur Samsung SyncMaster 750s
salut,

j'ai eut le cas, en fait ton tube est mort, il n'est plus assez lumineux(phosphore reflechissant a l'interieur qui est die!)
c'est du a un rafraichissement de ton ecran trop haut, du cout tu l'as tuer.

y as pas grand chose a faire, meme si tu augmente le tht, ca vas peut etre marcher qque temps, mais il est mort ton moniteur ....desole
paix a son ame !


A++

cacam

Numéro de l'article: 9474   |  De: cacam   |  Date: 2002-08-27 10:16:59
   RE: Luminosité moniteur Samsung SyncMaster 750s
Sur TRC mettre bobine alime filament en C/C tu gagne 6mois de vie

Numéro de l'article: 9605   |  De: Spike   |  Date: 2002-08-29 01:16:23
   RE: Luminosité moniteur Samsung SyncMaster 750s
Essaye d'abort le G2 avant de chipoter au tube, on sait jamais !

Il se trouve sur le transfo THT, c'est marqué G2 ou Screen dessus.

Augmente justqu'a ce que tu vois des lignes horizontale, ensuite tu diminues jusqu'a ce que tu ne les vois plus du tout sur un fond noir. Voilà, comme ca tu devrais avoir le réglages optimal pour ton tube.

Verifier le focus après réglages....

A+

Numéro de l'article: 9671   |  De: Ren   |  Date: 2002-08-29 21:59:47
   RE: Luminosité moniteur Samsung SyncMaster 750s
Fond noir et lumiere et contrast a "0" et chute G2 pour ne plus voir les lignes et que le tube semble eteint(spot eteint)....
PS: no signal et a freq fixe et faible (SOPS)et l'image force la synchro THT mais aussi l'alime Usys>regulation (sous dos ou console tout est tjrs parfait).


Numéro de l'article: 9679   |  De: Spike   |  Date: 2002-08-30 00:05:03

   PIC16F87x  
Héhé ,

Bon je recherche un exemple pour l'utilisation du bus I2C avec un
PIC16F87x.

LE PIC16F87x est le maitre dans mon cas , et le quartz est de 20Mhz

J'ai bessoin de communiquer avec PCF8573P , ca marche bien avec une routine 100% software . Mais j'ai pas encore utiliser la SPI ( hard ) pour ce protocole .

Si vous avez une routine ou exemples qui utilise la SPI pour cette tache bhen c sympa ,

A+



Numéro de l'article: 9466   |  De: ronald   |  Date: 2002-08-27 00:02:57
   RE: PIC16F87x
Salut
-----
Ce n'est pas le SPI qui gère l'i2C, c'est le MSSP.
Le SPI est un mode de fonctionnement particulier du MSSP, qui n'est pas L'i2C.

Voici un exemple de gestion de L'I2c en mode maître par un PIC16F87x, pour piloter une eeprom type 24c32. L'exemple est tiré de mon dernier livre.

Le programme est organisé en 3 couches :

- Couche supérieure : programme principal et sous-routines générales
- Couche intermédiaire : gestion de l'eeprom
- Couche inférieure : gestion de l'i2c.

Ainsi, tu peux extraire la gestion I2C du programme et avoir un exemple de leur utilisation.

A+
Bigonoff

;*****************************************************************************
; Exercice sur les accès I2C concrétisés par les échanges avec une 24C64. *
; Le programme écrit 40 octets dans l'eeprom, puis les lit en boucle et *
; envoie les octets lus à intervalle de 0,5 seconde sur le PORTB (LEDs) *
; *
;*****************************************************************************
; *
; NOM: lum_eep *
; Date: 06/07/2002 *
; Version: 1.0 *
; Circuit: Platine d'expérimentation *
; Auteur: Bigonoff *
; *
;*****************************************************************************
; *
; Fichier requis: P16F876.inc *
; *
;*****************************************************************************
; *
; Notes: L'eeprom est connectée sur le bus I2C (SCL + SDA) *
; A2, A1, et A0 de l'eeprom sont connectées à la masse *
; 8 LEDs sont connectées sur le PORTB *
; LE quartz travaille à 20MHz. *
; *
;*****************************************************************************


LIST p=16F876 ; Définition de processeur
#include ; fichier include

__CONFIG _CP_OFF & _DEBUG_OFF & _WRT_ENABLE_OFF & _CPD_OFF & _LVP_OFF & _BODEN_OFF & _PWRTE_ON & _WDT_ON & _HS_OSC

;_CP_OFF Pas de protection
;_DEBUG_OFF RB6 et RB7 en utilisation normale
;_WRT_ENABLE_OFF Le programme ne peut pas écrire dans la flash
;_CPD_OFF Mémoire EEprom déprotégée
;_LVP_OFF RB3 en utilisation normale
; _BODEN_OFF Reset tension hors service
;_PWRTE_ON Démarrage temporisé
;_WDT_ON Watchdog en service
;_HS_OSC Oscillateur haute vitesse (4Mhz
;*****************************************************************************
; ASSIGNATIONS SYSTEME *
;*****************************************************************************

; REGISTRE OPTION_REG (configuration)
; -----------------------------------
OPTIONVAL EQU B'10000000'
; RBPU b7 : 1= Résistance rappel +5V hors service

;*****************************************************************************
; ASSIGNATIONS PROGRAMME *
;*****************************************************************************

ADRESS EQU B'10100000' ; adresse eeprom = 1010 A2 A1 A0 R/W(0)
; l'adresse est déjà décalée (0xA0)
PR2VAL EQU D'249' ; Valeur de comparaison timer 2
CMPTVAL EQU D'125' ; 125 passages dans la routine d'interruption
; durée = Tcy*(PR2+1)*prédiv*postdiv*cmptval
; = 0,2µs * 250 * 16 * 5 * 125 = 0.5s.

;*****************************************************************************
; MACRO *
;*****************************************************************************

WBUF macro octet,offset ; place l'octet "octet" dans buffer+offset
movlw octet ; charger octet
movwf buffer+offset ; placer dans le buffer
endm

;*****************************************************************************
; VARIABLES BANQUE 0 *
;*****************************************************************************

; Zone de 80 bytes
; ----------------

CBLOCK 0x20 ; Début de la zone (0x20 à 0x6F)

buffer : 0x20 ; 32 octets de buffer
buflen : 1 ; longeur utilisée du buffer
cmpt : 1 ; compteur de passages d'interruption
flags : 1 ; 8 flags d'usage général
; b0 : 0.5s s'est écoulée
eepa : 2 ; valeur pour le pointeur d'adresse eeprom
ENDC ; Fin de la zone


;*****************************************************************************
; VARIABLES ZONE COMMUNE *
;*****************************************************************************

; Zone de 16 bytes
; ----------------

CBLOCK 0x70 ; Début de la zone (0x70 à 0x7F)
w_temp : 1 ; Sauvegarde registre W
status_temp : 1 ; sauvegarde registre STATUS
ENDC

;*****************************************************************************
; DEMARRAGE SUR RESET *
;*****************************************************************************

org 0x000 ; Adresse de départ après reset
goto init ; Initialiser

; ////////////////////////////////////////////////////////////////////////////

; I N T E R R U P T I O N S

; ////////////////////////////////////////////////////////////////////////////

;*****************************************************************************
; ROUTINE INTERRUPTION *
;*****************************************************************************
;*****************************************************************************
; ROUTINE INTERRUPTION *
;*****************************************************************************
;-----------------------------------------------------------------------------
; La routine d'interruption timer 2 est appelée toutes les
; (0,2µs * 80 * 250) = 4ms.
; au bout de 125 passages, une demi-seconde s'est écoulée, on positionne
; le flag
;-----------------------------------------------------------------------------

;sauvegarder registres
;---------------------
org 0x004 ; adresse d'interruption
movwf w_temp ; sauver registre W
swapf STATUS,w ; swap status avec résultat dans w
movwf status_temp ; sauver status swappé
bcf STATUS,RP0 ; passer banque0
bcf STATUS,RP1

; interruption timer 2
; --------------------
bcf PIR1,TMR2IF ; effacer le flag d'interruption
bsf flags,1 ; 8 ms écoulées
decfsz cmpt,f ; décrémenter compteur de passages
goto restorereg ; pas 0, fin de l'interruption
movlw CMPTVAL ; valeur de recharge du compteur
movwf cmpt ; recharger compteur
bsf flags,0 ; positionner flag

;restaurer registres
;-------------------
restorereg
swapf status_temp,w ; swap ancien status, résultat dans w
movwf STATUS ; restaurer status
swapf w_temp,f ; Inversion L et H de l'ancien W
; sans modifier Z
swapf w_temp,w ; Réinversion de L et H dans W
; W restauré sans modifier status
retfie ; return from interrupt


; ////////////////////////////////////////////////////////////////////////////
; P R O G R A M M E
; ////////////////////////////////////////////////////////////////////////////

;*****************************************************************************
; INITIALISATIONS *
;*****************************************************************************
init

; initialisation PORTS
; --------------------
BANKSEL PORTB ; passer banque 0
clrf PORTB ; sorties PORTB à 0
bsf STATUS,RP0 ; passer en banque1
clrf TRISB ; PORTB en sortie, les autres en entrée
movlw OPTIONVAL ; charger masque
movwf OPTION_REG ; initialiser registre option

; initialiser I2C
; ---------------
clrf SSPSTAT ; slew rate control en service, mode I²C
movlw D'11' ; valeur de recharge du BRG (400 Kbauds)
movwf SSPADD ; dans registre de recharge
bcf STATUS,RP0 ; passer banque 0
movlw B'00101000' ; module MSSP en service en mode I²C master
movwf SSPCON ; dans registre de contrôle

; initialiser variables
; ---------------------
clrf flags ; reset flags
movlw CMPTVAL ; pour 125 passages
movwf cmpt ; dans compteur de passages

; initialiser timer 2
; -------------------
movlw PR2VAL ; charger valeur de comparaison
BANKSEL PR2 ; passer banque 1
movwf PR2 ; initialiser comparateur
movlw B'00100110' ; timer2 on, prédiv = 16, post = 5
bcf STATUS,RP0 ; passer banque 0
movwf T2CON ; lancer timer 2

; lancer interruption timer 2
; ---------------------------
bsf STATUS,RP0 ; passer banque 1
bsf PIE1,TMR2IE ; interruption timer 2 en service
bcf STATUS,RP0 ; repasser banque 0
bsf INTCON,PEIE ; interruptions périphériques en service
bsf INTCON,GIE ; lancer les interruptions
goto start ; programme principal


;*****************************************************************************
; Attendre 0.5 seconde *
;*****************************************************************************
;-----------------------------------------------------------------------------
; attendre que 0.5s se soit écoulée depuis le précédent passage dans
; cette routine
;-----------------------------------------------------------------------------
wait
clrwdt ; effacer watchdog
btfss flags,0 ; flag positionné?
goto wait ; non, attendre flag
bcf flags,0 ; reset du flag
return ; et retour

;*****************************************************************************
; PROGRAMME PRINCIPAL *
;*****************************************************************************
start

; remplir le buffer d'émission
; ----------------------------
WBUF 0x01,0x00 ; placer l'octet dans le buffer
WBUF 0x02,0x01 ; placer l'octet dans le buffer
WBUF 0x04,0x02 ; placer l'octet dans le buffer
WBUF 0x08,0x03 ; placer l'octet dans le buffer
WBUF 0x10,0x04 ; placer l'octet dans le buffer
WBUF 0x20,0x05 ; placer l'octet dans le buffer
WBUF 0x40,0x06 ; placer l'octet dans le buffer
WBUF 0x80,0x07 ; placer l'octet dans le buffer
WBUF 0x40,0x08 ; placer l'octet dans le buffer
WBUF 0x20,0x09 ; placer l'octet dans le buffer
WBUF 0x10,0x0A ; placer l'octet dans le buffer
WBUF 0x08,0x0B ; placer l'octet dans le buffer
WBUF 0x04,0x0C ; placer l'octet dans le buffer
WBUF 0x02,0x0D ; placer l'octet dans le buffer
WBUF 0x01,0x0E ; placer l'octet dans le buffer
WBUF 0x00,0x0F ; placer l'octet dans le buffer
WBUF 0x01,0x10 ; placer l'octet dans le buffer
WBUF 0x03,0x11 ; placer l'octet dans le buffer
WBUF 0x07,0x12 ; placer l'octet dans le buffer
WBUF 0x0F,0x13 ; placer l'octet dans le buffer
WBUF 0x1F,0x14 ; placer l'octet dans le buffer
WBUF 0x3F,0x15 ; placer l'octet dans le buffer
WBUF 0x7F,0x16 ; placer l'octet dans le buffer
WBUF 0xFF,0x17 ; placer l'octet dans le buffer
WBUF 0xFE,0x18 ; placer l'octet dans le buffer
WBUF 0xFC,0x19 ; placer l'octet dans le buffer
WBUF 0xF8,0x1A ; placer l'octet dans le buffer
WBUF 0xF0,0x1B ; placer l'octet dans le buffer
WBUF 0xE0,0x1C ; placer l'octet dans le buffer
WBUF 0xC0,0x1D ; placer l'octet dans le buffer
WBUF 0x80,0x1E ; placer l'octet dans le buffer
WBUF 0x00,0x1F ; placer l'octet dans le buffer

; envoyer buffer dans eeprom
; --------------------------
clrf eepa ; adresse d'écriture = 00
clrf eepa+1 ; idem poids faible
movlw 0x20 ; 32 octets présents
movwf buflen ; placer dans le compteur d'octets
call eep_sendbuf ; envoyer le buffer dans l'eeprom

; placer 8 nouveaux octets dans le buffer
; ---------------------------------------
WBUF 0x55,0x00 ; placer l'octet dans le buffer
WBUF 0xAA,0x01 ; placer l'octet dans le buffer
WBUF 0x55,0x02 ; placer l'octet dans le buffer
WBUF 0xAA,0x03 ; placer l'octet dans le buffer
WBUF 0xF0,0x04 ; placer l'octet dans le buffer
WBUF 0x0F,0x05 ; placer l'octet dans le buffer
WBUF 0xF0,0x06 ; placer l'octet dans le buffer
WBUF 0x0F,0x07 ; placer l'octet dans le buffer

; envoyer buffer dans eeprom
; --------------------------
clrf eepa ; adresse d'écriture = 0x0020
movlw 0x20 ; adresse poids faible
movwf eepa+1 ; initialiser
movlw 8 ; 8 octets présents
movwf buflen ; placer dans le compteur d'octets
call eep_sendbuf ; envoyer le buffer dans l'eeprom



; traitement des lectures
; -----------------------
clrf eepa ; adresse de lecture = 00
clrf eepa+1 ; idem poids faible

loop1
call eep_adress ; initialiser pointeur d'adresse
call i2c_stop ; fin transaction
movlw D'40' ; 40 octets à lire
movwf buflen ; dans compteur d'octets
loop2
call eep_readc ; lire l'octet courant
movwf PORTB ; envoyer sur PORTB
call wait ; attendre 0.5s
decfsz buflen,f ; décrémenter compteur d'octets
goto loop2 ; pas dernier, suivant
goto loop1 ; dernier, on recommence

;*****************************************************************************
;*****************************************************************************
; ROUTINES EEPROM *
;*****************************************************************************
;*****************************************************************************

;*****************************************************************************
; LIRE L'OCTET COURANT *
;*****************************************************************************
;-----------------------------------------------------------------------------
; Lit l'octet pointé par le pointeur eeprom et le retourne dans w
; ensuite, clôture la communication
;-----------------------------------------------------------------------------
eep_readc
call i2c_start ; envoyer start-condition
movlw ADRESS+1 ; charger adresse eeprom en lecture
call i2c_write ; envoyer adresse eeprom
call i2c_read ; lire l'octet
call i2c_stop ; fin du transfert
return ; et retour

;************************ *****************************************************
; ENVOYER LE BUFFER DANS L'EEPROM *
;*****************************************************************************
;-----------------------------------------------------------------------------
; Envoie le buffer dans l'eeprom
; buffer contient les données à envoyer
; buflen contient le nombre d'octets à envoyer (détruit après l'exécution)
; eepa contient l'adresse d'écriture
;-----------------------------------------------------------------------------
eep_sendbuf
call eep_adress ; initialiser pointeur adresse
movlw buffer ; charger adresse buffer
movwf FSR ; dans pointeur
eep_sendb1
movf INDF,w ; charger un octet
call i2c_write ; l'envoyer
incf FSR,f ; incrémenter pointeur buffer
decfsz buflen,f ; décrémenter nbre d'octets restants
goto eep_sendb1 ; pas fini, suivant
call i2c_stop ; fin du transfert
return ; et retour

;*****************************************************************************
; INITIALISER LE POINTEUR D'ADRESSE
;*****************************************************************************
;-----------------------------------------------------------------------------
; envoie le start-condition, puis l'adresse de l'eeprom
; ensuite, teste le ACK
; Si NOACK, on envoie le repeated start-condition, puis de nouveau l'adresse
; si toujours NOACK, on recommence
; Si ACK, on envoie les 2 octets d'adresse contenus dans eepa
;-----------------------------------------------------------------------------
eep_adress
; envoyer adresse circuit tant que pas ACK
; ----------------------------------------
call i2c_start ; envoyer start-condition
eep_adress1
movlw ADRESS ; charger adresse eeprom + écriture
call i2c_write ; écrire adresse eeprom
bsf STATUS,RP0 ; passer en banque1
btfss SSPCON2,ACKSTAT ; tester ACK reçu
goto eep_adressok ; oui, poursuivre OK
call i2c_rstart ; non, envoyer repeated start-condition
goto eep_adress1 ; recommencer test

; placer 2 octets d'adresse dans pointeur
; ---------------------------------------
eep_adressok
bcf STATUS,RP0 ; repasser banque 0
movf eepa,w ; charger poids fort adresse
call i2c_write ; écrire poids fort
movf eepa+1,w ; charger poids faible adresse
call i2c_write ; écrire poids faible
return ; et retour

;*****************************************************************************
;*****************************************************************************
; ROUTINES I2C *
;*****************************************************************************
;*****************************************************************************
;-----------------------------------------------------------------------------
; On attend que chaque commande soit terminée avant de sortir de la
; sous-routine correspondante
;-----------------------------------------------------------------------------
IWAIT macro REGISTRE,BIT ; attendre effacement du bit du registre
clrwdt ; effacer watchdog
btfsc REGISTRE,BIT ; bit effacé?
goto $-2 ; non, attendre
bcf STATUS,RP0 ; repasser en banque 0
endm ; fin de macro

;*****************************************************************************
; ENVOYER LE START-CONDITION *
;*****************************************************************************
i2c_start
bsf STATUS,RP0 ; passer en banque 1
bsf SSPCON2,SEN ; lancer le start-condition
IWAIT SSPCON2,SEN ; attendre fin start-condition
return ; et retour

;*****************************************************************************
; ENVOYER LE REPEATED START-CONDITION *
;*****************************************************************************
i2c_rstart
bsf STATUS,RP0 ; passer en banque 1
bsf SSPCON2,RSEN ; lancer le repeated start-condition
IWAIT SSPCON2,RSEN ; attendre fin repeated start-condition
return ; et retour

;*****************************************************************************
; ENVOYER LE STOP-CONDITION *
;*****************************************************************************
i2c_stop
bsf STATUS,RP0 ; passer en banque 1
bsf SSPCON2,PEN ; lancer le stop-condition
IWAIT SSPCON2,PEN ; attendre fin stop-condition
return ; et retour

;*****************************************************************************
; ENVOYER LE ACK *
;*****************************************************************************
i2c_ack
bsf STATUS,RP0 ; passer en banque 1
bcf SSPCON2,ACKDT ; le bit qui sera envoyé vaudra " 0 "
bsf SSPCON2,ACKEN ; lancer l'acknowledge (= ACKDT = 0 = ACK)
IWAIT SSPCON2,ACKEN ; attendre fin ACK
return ; et retour

;*****************************************************************************
; ENVOYER LE NOACK *
;*****************************************************************************
i2c_noack
bsf STATUS,RP0 ; passer en banque 1
bsf SSPCON2,ACKDT ; le bit qui sera envoyé vaudra " 1 "
bsf SSPCON2,ACKEN ; lancer l'acknowledge (= ACKDT = 1 = NOACK)
IWAIT SSPCON2,ACKEN ; attendre fin NOACK
return ; et retour

;*****************************************************************************
; ENVOYER UN OCTET *
;*****************************************************************************
;-----------------------------------------------------------------------------
; L'octet est passé dans W
;-----------------------------------------------------------------------------
i2c_write
movwf SSPBUF ; lancer l'émission de l'adresse en mode écriture
bsf STATUS,RP0 ; passer en banque 1
IWAIT SSPSTAT,R_W ; attendre émission terminée
return ; et retour

;*****************************************************************************
; LIRE UN OCTET *
;*****************************************************************************
;-----------------------------------------------------------------------------
; L'octet est retourné dans W
;-----------------------------------------------------------------------------
i2c_read
bsf STATUS,RP0 ; passer en banque 1
bsf SSPCON2,RCEN ; lancer la lecture
IWAIT SSPCON2,RCEN ; attendre réception terminée
movf SSPBUF,w ; charger octet reçu
return ; et retour

END ; directive fin de programme



Numéro de l'article: 9487   |  De: Bigonoff   |  Date: 2002-08-27 13:38:52
   RE: PIC16F87x
Grand merçi pour ta routine ....




Numéro de l'article: 9489   |  De: ronald   |  Date: 2002-08-27 14:19:17

   eprom 24w166  
je souhaite programmer le 24w166 mais je n'arrive pas à trouver sur internet les instructions et comment les utilisées. Si quelqu'un les connait, merci de me les envoyées. Merci


Numéro de l'article: 9467   |  De: milas   |  Date: 2002-08-27 03:03:40

   onde sinusoidale en onde carrée  
salut;
est ce que qqu'un peut m'expliquer comment transformer une onde sinusoidale de 50Hz en onde carrée en utilisant des AOP.
les sinusoides ont un module de 9V.
si vous avez une adresse de la ou je peux trouver la doc veuillez me le montrer.
Merci d'avance

Numéro de l'article: 9471   |  De: dma   |  Date: 2002-08-27 09:03:57
   RE: onde sinusoidale en onde carrée
tu met l'entrée + de l'ampli à la masse et l'entré moins à ton entré sinusoiale,
si + >- sortie =Vcc
si +<- sortie =Vee
Vcc et Vee sont les polarisation de ton ampli.
a+

Numéro de l'article: 9472   |  De: Fabrice   |  Date: 2002-08-27 09:49:48
   RE: onde sinusoidale en onde carrée
perso, j'aurais mis le - à la masse et le signal sur l'entrée +.
Non ?

Numéro de l'article: 9533   |  De: Alex404   |  Date: 2002-08-28 08:05:57
   RE: onde sinusoidale en onde carrée
oui exact

Numéro de l'article: 9538   |  De: Fabrice   |  Date: 2002-08-28 11:00:24
   RE: onde sinusoidale en onde carrée
Les deux fonctionnent, La seule différence est que la sortie est inversée.

A+ fthierry

Numéro de l'article: 9542   |  De: fthierry   |  Date: 2002-08-28 11:16:23

   Alimentation a decoupage ??  
Salut
je souhaiterais réaliser une alimentation a decoupage de type boost, pour faire une 40aine de volt sous une 10aine d'ampere avec du 12volt automobile.
Je suis a le recherche de circuit specialiser realisant cette fonction, soit tout integrer dans un multiwatt par exemple, ou bien un circuit drivant des mosfet par exemple.

Merci pour votre aide et pour les reference de composant que vous pourrez me fournir :-)

Bye a tous @+

Numéro de l'article: 9482   |  De: RolLie_TyLer_HC11   |  Date: 2002-08-27 11:36:19

   adaptateur S-VHS  
je suis actellement a la recherche d'un ou plusieurs schemas de cablage pour une sortie S-VHS DIN 4 broche en peritel et S-VHS DIN 4 broche en video composite


merci de pense a moi

@+
Goupil

Numéro de l'article: 9484   |  De: goupil   |  Date: 2002-08-27 11:56:32
   RE: adaptateur S-VHS
Salut,

Sache que si tu veux passer du S-Vidéo (prise S-vhs)sur une péritel, il faut que ton téléviseur soit compatible S-vidéo par la prise péritel, ce qui est assez rare...

Par contre, il est impossible de passer du s-vidéo au composite par un simple câblage: il faut un transcodeur.

Sinon, je regarde le câblage pour la péritel.

JF

Numéro de l'article: 9498   |  De: Jean-François   |  Date: 2002-08-27 17:04:05
   RE: adaptateur S-VHS
pour passer de la S-VIDEO a la péritel y a pas de probleme la tele accepte la S-VIDEO

mais parcontre j'ai touver un site avec le cablage de la S-VIDEO au composite, en faite il relie la luminance et la chrominance sur le point millieu et la masse a l'exterieur

c pourquoi je me renseigne sa m'a paru trop simple

mais si tu peux me dire aussi ou trouvé le transcodeur ou meme le schemas electronique se serai sympas

@+
Goupil


Numéro de l'article: 9547   |  De: goupil   |  Date: 2002-08-28 12:06:21
   RE: adaptateur S-VHS
si ta TV acepte le s-vidéo, vas-y la qualité ne peut etre que meilleure !
pour le schéma de cablage, il y en as lur le net

pour le transcodeur, electronique pratique en a publié un au mois de mars 2000

Numéro de l'article: 9555   |  De: Petrus   |  Date: 2002-08-28 13:37:10
   RE: adaptateur S-VHS
merci pour les renseignements

je vient de trouver un schema pour passer de la S-video sans utilise un transcodeur si sa interesse voici le schema

masse luminance 1-----+
+--------masse Rca composite
masse chrominance 2---+

luminance 3-----------+
+---------Point millieu RCA composite
chrominance 4----ll---+
470pF


condensateur 470pF 10V mini

Numéro de l'article: 9572   |  De: goupil   |  Date: 2002-08-28 16:44:11
   RE: adaptateur S-VHS
oui c'est bon ton schéma

A+

Numéro de l'article: 9586   |  De: Ren   |  Date: 2002-08-28 19:33:19

   Circuit PLD  
Salut,
je souhaiterai me mette au circuit logique programmable, et je voulais savoir si k1 avait des url de site avec des cours sur ces composants.
La facon de les programmer, le language VHDL etc...

Merci
A plus

Numéro de l'article: 9497   |  De: RolLie_TyLer_HC11   |  Date: 2002-08-27 16:34:54
   RE: Circuit PLD
voir le site web du constructeur Xilinx
www.xilinx.com
www.adaptyv.com/fr

Slatrach
http://membres.lycos.fr/slatrach/
bon courage

Numéro de l'article: 9511   |  De: slatrach   |  Date: 2002-08-27 22:24:57

   moteur pas a pas  
Bonjour a tous,

voila, j'ai recuperé des vieux moteurs pas a pas,
la couleur des fils est elle standard ?
comment je reconnait les differentes phases ?
comment connaitre le voltage du moteur ?

vous l'avez compris, il me manque trop d'info
pour les exploiter.

merci d'avance pour votre aide.

A+
ehlo.


Numéro de l'article: 9499   |  De: ehlo   |  Date: 2002-08-27 18:03:08
   RE: moteur pas a pas
Salut

1°) les moteurs pas à pas travaille en courants et pas en tension .

2°) Il existe 2 catégories de moteur pas à pas

a) moteur bipolaire
b) moteur unipolaire

a) les moteur bipolaire :

tu peut reconnaitre ce type de moteur si il y a 4 fils .
c'est moteur sont plus puissant pour leur même en unipolaire
mais un peux plus compliquer a commander , car il faut inverser
le sens du courant .

b) les moteur unipolaire :

C'est moteur sont géneralement 5 ou 6 fils
dans le cas ou c'est 5 fils tu retrouveras un commun et 4 phase

R
=
===R===C====R==== Donc tu recherche le commun
= et tu retrouve les 4 phases
R

tu trouveras sans problème des infos sur le net sur les moteurs
pour ce qui est du courant bhen la faut le faire progressivement
du augmente si il chauffe inormalement bhen tu diminue
attention que si tu fait circuler du courant dans 1 phase bhen
il vas chauffer vite il faut le faire tourner

A+



Numéro de l'article: 9512   |  De: ronald   |  Date: 2002-08-27 22:32:27
   RE: moteur pas a pas
Grand Merci,

encore une chose, dans le cas de 6 fils,
il y a 2 communs ?

sur les infos que j'ai pu "pecher" sur le net,
en général, les moteurs pas à pas, sont derrière un ensemble de DARLINGTONs, par exemple : ULN2803.

Dans le cas d'une utilisation avec un PIC + ULN, comment je peux obtenir une modification du courant et non de la tension ?

En +, sur les 6 fils, je pensais trouver 4 phases, une masse, et une alim.

Merci de m'exliquer... J'ai tout faux ???

Encore merci
@+
ehlo.




Numéro de l'article: 9588   |  De: ehlo   |  Date: 2002-08-28 20:12:24
   RE: moteur pas a pas
C'est un moteur de la famille unipolaire .

Donc tu a deux commun .

Il te suffit de trouver la paire c'est a dire Un commun et deux phase et un autres commun et deux phase.

Puis tu m'est les deux commun ensemble a 0V
puis tu recherche les phases on vas dire ABCD .

donc tu m'est du +5V sur une phase et le moteur doit-être bloquer ,
puis tu retire le 5V et tu recherche la phase B puis la C et la D

Quand tu a trouver les phases bhen tu m'est tu 5V sur A puis tu retire puis B puis tu retire puis C puis tu retire puis D puis A etc...

pour le faire tourner dans le sens contraire bhen tu fait l'inverse
D puis C puis B puis A puis D etc ...

La tu travaille en mode pas entier ...

Tu peut travailler en mode demi-pas ,

alors tu remet tu courant sur A puis après sur B sans retirer A puis tu retire A puis tu met C sans retirer B puis tu retire B et etc ...

Pour la régulation tu peut utiliser des AOP mais si c'est un moteur qui est petit de l'ordre de 500mA bhen tu peut travailler en tension

Il existe des circuits spécialiser pour la commande de moteur , mais un UNL2803 peut faire laffaire commencer ...

A+


Numéro de l'article: 9598   |  De: byte   |  Date: 2002-08-28 23:38:00
   RE: moteur pas a pas
Merci !

j'essaie et je vous tient au courant.

A+

Numéro de l'article: 9695   |  De: ehlo   |  Date: 2002-08-30 09:05:54